A1

附錄 I

這裡是 Lox 的完整文法。介紹語言各部分的章節中包含了該部分的文法規則，但這裡將它們全部收集到一處。

A1.1語法文法

語法文法用於將線性的標記序列解析為巢狀的語法樹結構。它從匹配整個 Lox 程式（或單個 REPL 輸入）的第一條規則開始。

program        → declaration* EOF ;

A1.1.1宣告

程式是一系列的宣告，這些宣告是綁定新識別符號的語句或任何其他語句類型。

declaration    → classDecl
               | funDecl
               | varDecl
               | statement ;

classDecl      → "class" IDENTIFIER ( "<" IDENTIFIER )?
                 "{" function* "}" ;
funDecl        → "fun" function ;
varDecl        → "var" IDENTIFIER ( "=" expression )? ";" ;

A1.1.2語句

剩餘的語句規則會產生副作用，但不會引入綁定。

statement      → exprStmt
               | forStmt
               | ifStmt
               | printStmt
               | returnStmt
               | whileStmt
               | block ;

exprStmt       → expression ";" ;
forStmt        → "for" "(" ( varDecl | exprStmt | ";" )
                           expression? ";"
                           expression? ")" statement ;
ifStmt         → "if" "(" expression ")" statement
                 ( "else" statement )? ;
printStmt      → "print" expression ";" ;
returnStmt     → "return" expression? ";" ;
whileStmt      → "while" "(" expression ")" statement ;
block          → "{" declaration* "}" ;

請注意，block 是一個語句規則，但也用作其他一些規則（例如函數體）中的非終端符號。

A1.1.3表達式

表達式會產生值。Lox 有許多具有不同優先級的一元和二元運算符。一些語言的文法並未直接編碼優先級關係，而是在其他地方指定。在這裡，我們為每個優先級使用單獨的規則使其明確。

expression     → assignment ;

assignment     → ( call "." )? IDENTIFIER "=" assignment
               | logic_or ;

logic_or       → logic_and ( "or" logic_and )* ;
logic_and      → equality ( "and" equality )* ;
equality       → comparison ( ( "!=" | "==" ) comparison )* ;
comparison     → term ( ( ">" | ">=" | "<" | "<=" ) term )* ;
term           → factor ( ( "-" | "+" ) factor )* ;
factor         → unary ( ( "/" | "*" ) unary )* ;

unary          → ( "!" | "-" ) unary | call ;
call           → primary ( "(" arguments? ")" | "." IDENTIFIER )* ;
primary        → "true" | "false" | "nil" | "this"
               | NUMBER | STRING | IDENTIFIER | "(" expression ")"
               | "super" "." IDENTIFIER ;

A1.1.4輔助規則

為了使上述規則更簡潔一些，一些文法被拆分成了幾個可重複使用的輔助規則。

function       → IDENTIFIER "(" parameters? ")" block ;
parameters     → IDENTIFIER ( "," IDENTIFIER )* ;
arguments      → expression ( "," expression )* ;

A1.2詞法文法

詞法文法被掃描器用於將字元分組為標記。語法是上下文無關的，而詞法文法是正規的—請注意，這裡沒有遞迴規則。

NUMBER         → DIGIT+ ( "." DIGIT+ )? ;
STRING         → "\"" <any char except "\"">* "\"" ;
IDENTIFIER     → ALPHA ( ALPHA | DIGIT )* ;
ALPHA          → "a" ... "z" | "A" ... "Z" | "_" ;
DIGIT          → "0" ... "9" ;